Hallo, bin ganz neu hier, daher erst einmal ein freundliches Hallo von mir.

Ja, und ich habe gleich ein Problem.
Bei mir wurde vor kurzem der Netzzugang auf VDSL umgestellt und dafür habe ich natürlich auch einen neuen Router bekommen. Und zwar die Homebox 6641.
Dafür hatte ich hier im Forum auch ein Script gefunden, das lief.

Leider funktionierte aber mein DECT-Telefon mit diesem Router nicht. o2 hatte mir dann angeboten, es mal mit der 6441 zu versuchen und damit klappt es auch sehr gut.

Nur leider..... der Reconnect will nicht mehr.
Ich suche jetzt also ein Script für die o2 Homebox 6441 von Astoria.
Wäre toll, wenn mir jemand helfen könnte.

Hmmmm....
Niemand eine Idee?

Niemand da, der dieses Teil kennt? Oder mir einen Tipp geben kann, was ich machen kann?

Originally Posted by Hober Mallow

... Und zwar die Homebox 6641.

ich dachte die 6441?

Dank Upgrade auf VDSL habe ich auch diesen Router (o2 Homebox 6441) bekommen. Im internet habe ich kein Reconnect-Script gefunden, daher habe ich mir eins gebaut.

Leider lässt sich der Reconnect nicht über LiveHeaders realisieren, da diverse Funktionen benötigt werden (md5 und aes512 hashing, base64).

Dies ist ein AutoIt-Script. Es kann als Standalone-EXE kompiliert werden und dann als externer Restart in JD eingestellt werden.

Benötigt wird AutoIt und die WinHttp-AutoIt UDF.

Kurzanleitung:

• AutoIt installieren
• Ein neues Script in AutoIt erstellen, mein Script dort einfügen und abspeichern
• WinHttp-AutoIt UDF herunterladen und die au3-Dateien im gleichen Ordner speichern
  ( github.com/dragana-r/autoit-winhttp/releases/download/1.6.3.9/1.6.3.9.zip )
• In AutoIt das Script kompilieren (Tools -> Build, oder F7-Taste)
• Die im Scriptverzeichnis erstellte .exe-Datei zum reconnecten benutzen

Hinweis:
Falls Du ein Router-Passwort eingerichtet hast, braucht das Script es. Dieses kann per Parameter an die .exe-Datei übergeben werden oder Du kannst es direkt in die Datei mit einkompilieren.
Dazu diese Variable

Local $g_sRouterPass = -1

ändern in

Local $g_sRouterPass = 'mein passwort'

Um das Passwort per Parameter zu übergeben

meine.exe pass meinpasswort

PHP Code:

; ######################################
; ## o2 HomeBox 6441 reconnect script ##
; ## tested on firmware 1.01.23v      ##
; ## by rbybbl                        ##
; ######################################

#include 'WinHttp.au3'
#include <Array.au3>
#include <Date.au3>
#include <Crypt.au3>
Global Const $CALG_SHA_512 = 0x0000800E

; ##################
; ###  SETTINGS  ###
; ##################
Local $g_sRouterHost = 'o2.box'
Local $g_sRouterPass = -1
Local $g_sRouterMode = 'reconnect'

; ### DO NOT EDIT
If $CmdLine[0] > 0 Then
    For $i = 1 To $CmdLine[0] Step 2
        If $i >= $CmdLine[0] Then ExitLoop
        $CmdLine[$i] = StringLower($CmdLine[$i])
        $CmdLine[$i+1] = StringLower($CmdLine[$i+1])

        If StringLeft($CmdLine[$i], 4) = 'host' Then
            $g_sRouterHost = $CmdLine[$i+1]

        ElseIf StringLeft($CmdLine[$i], 4) = 'pass' Then
            $g_sRouterPass = $CmdLine[$i+1]

        ElseIf $CmdLine[$i] = 'mode' And ($CmdLine[$i+1] = 'reconnect' Or $CmdLine[$i+1] = 'reboot') Then
            $g_sRouterMode = $CmdLine[$i+1]
        EndIf
    Next
EndIf

Local $g_hOpen = _WinHttpOpen()
Local $g_hConnect = _WinHttpConnect($g_hOpen, $g_sRouterHost)
Local $g_sToken = _RouterLogin()

If $g_sRouterMode = 'reconnect' Then
    ; perform reconnect
    ConsoleWrite('reconnecting' & @CRLF)
    _RouterReconnect()
    _RouterLogout()
ElseIf $g_sRouterMode = 'reboot' Then
    ConsoleWrite('rebooting' & @CRLF)
    _RouterReboot()
EndIf

_WinHttpCloseHandle($g_hConnect)
_WinHttpCloseHandle($g_hOpen)

Exit

; #################
; ### FUNCTIONS ###
; #################

Func _RouterLogin()
    If $g_sRouterPass <> '' And $g_sRouterPass <> False And $g_sRouterPass <> -1 Then
        Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'POST', 'login.cgi', Default, 'pws=' & _EncryptPassword($g_sRouterPass))
        If @error Then Exit MsgBox(16, 'Error', 'Login request failed')
    EndIf

    Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'GET')
    If @error Then Exit MsgBox(16, 'Error', 'Token request failed')

    Local $aToken = StringRegExp($sRequest, '(?i)data:image/gif;base64,[a-z0-9+/]+///[a-z0-9+/]{31}([^"]+)"', 1)
    Local $sToken = BinaryToString(_Base64Decode($aToken[0]))

    Return $sToken
EndFunc

Func _RouterLogout()
    If $g_sRouterPass <> '' And $g_sRouterPass <> False And $g_sRouterPass <> -1 Then
        Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'POST', 'logout.cgi')
        If @error Then Exit MsgBox(16, 'Error', 'Logout request failed')
    EndIf
EndFunc

Func _RouterReconnect()
    Local $aCommandSequence[2] = ['wan_stop', 'wan_start']
    For $i = 0 To UBound($aCommandSequence)-1
        Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'POST', 'apply_abstract.cgi', Default, 'action=' & $aCommandSequence[$i] & '&httoken=' & $g_sToken)
        If @error Then Exit MsgBox(16, 'Error', 'Reconnect request failed')
        If $i = 0 Then Sleep(500)
    Next
    While Not _RouterIsConnected()
        Sleep(500)
    WEnd
EndFunc

Func _RouterReboot()
    Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'POST', 'apply_abstract.cgi', Default, 'action=ui_reboot&httoken=' & $g_sToken)
    If @error Then Exit MsgBox(16, 'Error', 'Reboot request failed')
EndFunc

Func _RouterInfo()
    Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'GET', 'cgi/cgi_diagnostic.js?_tn=' & $g_sToken)
    If @error Then Exit MsgBox(16, 'Error', 'Info request failed')
    Local $aInfo = StringRegExp($sRequest, '(?i)"(WAN_IP4_Addr|LAN_IP4_Addr|nWANConnectStatus0|sys_uptime)",\s?"?\d+"?,\s?"([^"]+)"', 3)
    ;_ArrayDisplay($aInfo)
    ;MsgBox(0,0,$sRequest)
EndFunc

Func _RouterIsConnected()
    Local $sRequest = _WinHttpSimpleRequest($g_hConnect, 'GET', 'cgi/cgi_diagnostic.js?_tn=' & $g_sToken)
    If @error Then Exit MsgBox(16, 'Error', 'Info request failed')
    Return StringRegExp($sRequest, '(?i)"nWANConnectStatus0",\s?"?\d+"?,\s?"Connected"')
EndFunc

Func _EncryptPassword($sPassword)
    Local $sTmpMd5 = _Crypt_HashData($sPassword, $CALG_MD5)
    $sTmpMd5 = StringLower(StringTrimLeft($sTmpMd5, 2))
    Local $sTmpSha512 =  _Crypt_HashData($sTmpMd5, $CALG_SHA_512)
    $sTmpSha512 = StringLower(StringTrimLeft($sTmpSha512, 2))
    Return $sTmpSha512
EndFunc

Func _Base64Decode($input_string)
    Local $struct = DllStructCreate('int')
    $a_Call = DllCall('Crypt32.dll', 'int', 'CryptStringToBinary', 'str', $input_string, 'int', 0, 'int', 1, 'ptr', 0, 'ptr', DllStructGetPtr($struct, 1), 'ptr', 0, 'ptr', 0)
    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, '')
    EndIf

    Local $a = DllStructCreate('byte[' & DllStructGetData($struct, 1) & ']')
    $a_Call = DllCall('Crypt32.dll', 'int', 'CryptStringToBinary', 'str', $input_string, 'int', 0, 'int', 1, 'ptr', DllStructGetPtr($a), 'ptr', DllStructGetPtr($struct, 1), 'ptr', 0, 'ptr', 0)
    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, '')
    EndIf

    Return DllStructGetData($a, 1)
EndFunc 


eine Funktion zum rebooten des Routers habe ich ebenfalls eingebaut!

ich habe auch eine PHP-Version erstellt (zum zeitgesteuerten Reboot/Reconnect per Cronjob/Remote) die ich bei Interesse posten kann..

Viele Grüße
rbybbl

Originally Posted by rbybbl

ich dachte die 6441?

Sorry, da habe ich mich vielleicht etwas unklar ausgedrückt.

Zuerst hatte ich eine Homebox 6641. Dafür hatte ich hier auch ein Skript gefunden. Mit diesem Router funktionierte aber mein Telefon nicht. Deshalb hat o2 ihn gegen eine Homebox 6441 getauscht. Damit funktioniert zwar das Telefon aber der Reconnect nicht.

Also,
mein jetziger Router ist tatsächlich eine Homebox 6441.

Leider kann ich mit deiner Lösung nichts anfangen, da ich kein Windows benutze, sondern Linux.

Ich wage nicht zu offen, dass du auch dafür eine Lösung hast.

Originally Posted by Hober Mallow

Sorry, da habe ich mich vielleicht etwas unklar ausgedrückt.

Zuerst hatte ich eine Homebox 6641. Dafür hatte ich hier auch ein Skript gefunden. Mit diesem Router funktionierte aber mein Telefon nicht. Deshalb hat o2 ihn gegen eine Homebox 6441 getauscht. Damit funktioniert zwar das Telefon aber der Reconnect nicht.

Also,
mein jetziger Router ist tatsächlich eine Homebox 6441.

Leider kann ich mit deiner Lösung nichts anfangen, da ich kein Windows benutze, sondern Linux.

Ich wage nicht zu offen, dass du auch dafür eine Lösung hast.

Naja, wenn Du Apache und PHP installierst, dann könntest Du mein PHP-Script benutzen
Aber extra einen Webserver nur für einen Router-Reconnect aufzusetzen ist vielleicht etwas übertrieben..

Bin mir nicht sicher, aber ich denke es sollte in Linux per Shellscript leicht zu lösen sein. Leider hab ich aber sehr wenig Linux-Erfahrung.

Eventuell könnte man doch ein Live-Headers-Script für JD schreiben (dazu müsste man das den Hashwert des Login-Passworts aber als Variable anlegen).
Ich versuche es mal bei Gelegenheit!

Edit: Mit Live-Headers-Script geht es leider nicht, da JD keine Möglichkeit bietet eine base64-Zeichenkette zu entschlüsseln :(

Edit 2:
Ok, habe ein Shell-Script erstellt. Es gibt bestimmt elegantere Wege das zu realisieren, hab praktisch keine Linux-Erfahrung, aber es funktioniert bei mir. Die Variable ROUTER_HOST erklärt sich von selbst, das Passwort muss als Hash-Wert vorliegen. Einen Hashwert kannst Du z.B. auf **External links are only visible to Support Staff**www.hashgenerator.de/ (hashgenerator punkt de) erstellen. Gib Dein Klartext-Passwort ein und erstelle einen MD5-Hash. Kopiere diesen (ohne Leerzeichen am Anfang und Ende) und benutze ihn als Input für ein SHA512-Hash. Das Ergebnis dann in die Variable ROUTER_PASS kopieren.

PHP Code:

#!/bin/sh
ROUTER_HOST="192.168.1.1"
ROUTER_PASS="b0f4337213779e16df1304962........................................................................."

# send login post request
curl -s -d "pws=$ROUTER_PASS" "$ROUTER_HOST/login.cgi" > /dev/null

# get the token from index page and save as var
ROUTER_TOKEN=$(curl --silent "$ROUTER_HOST/" | grep -ioP 'data:image/gif;base64,[a-z0-9+/]+///[a-z0-9+/]{31}\K([^"]+)' | base64 --decode)

# send disconnect post request
curl -s -d "action=wan_stop&httoken=$ROUTER_TOKEN" "$ROUTER_HOST/apply_abstract.cgi" > /dev/null

# to be sure
sleep 1

# send connect post request
curl -s -d "action=wan_start&httoken=$ROUTER_TOKEN" "$ROUTER_HOST/apply_abstract.cgi" > /dev/null

# wait for connected state
while true
do
    if curl -s "$ROUTER_HOST/cgi/cgi_diagnostic.js?_tn=$ROUTER_TOKEN" | grep -qiP '"nWANConnectStatus0",\s?"?\d+"?,\s?"Connected"'; then
        break
    fi
    sleep 1
done
# send logout request
curl -s -d "" "$ROUTER_HOST/logout.cgi" > /dev/null 


rbybbl... Du bist super!

Das Skript funktioniert einwandfrei. Der Reconnect ist sogar überraschend schnell, gerade mal so um die 13 Sekunden.

Vielen, vielen Dank für deine Mühe!

Gerne, schön das es funktioniert!

Kannst den Thread auch als [Reconnect funktioniert] markieren, nützlich für andere User!

Viele Grüße

Hm....
... irgendwie bin ich zu blöd, den Thread-Titel zu ändern.

Originally Posted by Hober Mallow

Hm....
... irgendwie bin ich zu blöd, den Thread-Titel zu ändern.

ach keine Ahnung, vielleicht machen das auch nur Moderatoren?
egal :D

Hallo,

ich habe jetzt auch die O2 Homebox 6641. Möchte nun mit dem jDownloader den Router auch Reconnecten.
Wollte das nun mit der Anleitung von rbybbl umsetzen. Aber leider scheitere ich schon am runter laden von WinHttp-AutoIt UDF. Wo kann ich das runter laden?
Habe leider keine Erfahrung mit Scripts.

@rbybbl Du hast geschrieben du hast auch eine PHP Version erstellt. Ist diese Version leichter für mich zum benutzen?
Ich benutze Windows.

Danke
BEWEWA

[Knotte80]

Hallo,

danke für die super Anleitung!
Die WinHttp-AutoIt UDF gibt es übrigens hier: **External links are only visible to Support Staff****External links are only visible to Support Staff**

Habe nun die EXE kompiliert. Da ich kein Router-Passwort benutze, habe ich nix geändert. Im JD kommt dann aber beim Starten des Scripts die Meldung "no router password set". Also hab ich ein Passwort eingestellt und dieses im Script ergänzt, aber es kommt wieder die Fehlermeldung.
Was nun?

Leider wird mir der Link für WinHttp-AutoIt UDF nicht angezeigt. Kannst du mir den Link als Private Nachricht schicken?Danke

Originally Posted by Knotte80

Hallo,

danke für die super Anleitung!
Die WinHttp-AutoIt UDF gibt es übrigens hier: **External links are only visible to Support Staff**...

Habe nun die EXE kompiliert. Da ich kein Router-Passwort benutze, habe ich nix geändert. Im JD kommt dann aber beim Starten des Scripts die Meldung "no router password set". Also hab ich ein Passwort eingestellt und dieses im Script ergänzt, aber es kommt wieder die Fehlermeldung.
Was nun?

Du könntest ein Router-Passwort einstellen? Wäre eine Lösung...

Habe mein Script aktualisiert (s. alten Beitrag), jetzt sollte es auch bei Routern ohne Passwort funktionieren..

Die UDF-Dateien gibt es hier: github.com/dragana-r/autoit-winhttp/releases/download/1.6.3.9/1.6.3.9.zip

Einen Riesengroßen Dank!
Es funktioniert sehr gut und ist ziemlich fix!
Einfach Klasse.
Toll, dass es Leute gibt, die sowas coden (und ihr Wissen teilen) :-)

Hallo rbybbl, danke für das Script. Habe es nun auch ausprobiert und es klappt wunderbar und ist auch sehr schnell!!

Danke nochmal für deine Hilfe!!!

@rbybbl

Vielen Dank, dass du deine Informatik-Kenntnisse gemeinnützig gebraucht hast, um die obigen Skripte zu coden.
Leider gab es vor kurzem ein Firmware-Upgrade für die o2 Homebox 6441 auf 1.01.30v. Dadurch funktioniert das Reconnect-Skript leider nicht mehr(, aber das Reboot-Skript wohl schon). Könntest du daher vielleicht noch einmal einen Teil deiner kostbaren Zeit investieren, um das Skript zu aktualisieren? Vielen Dank im Voraus.

Beste Grüße
Beryus

Hi,

mit minimalen Änderungen funktioniert das Shellskript von rbybbl bei mir einwandfrei.

Evtl. geht auch das AutoIt skript von rbybbl wieder (falls es nicht geht momentan, ich kann das nicht testen), wenn man:

nWANConnectStatus0

durch

WANConnectStatus0

ersetzt. Die zugehörige Zeile aus "$ROUTER_HOST/cgi/cgi_diagnostic.js?_tn=$ROUTER_TOKEN" lautet zumindest

addCfg("WANConnectStatus0", "00000000000", "Connected");

Ich hoffe, das hilft weiter.

Hier meine komplette reconnect.sh zum kopieren. Gestestet auf FW 1.01.30
Router IP und Passworthash müssen nach wie vor angepasst werden.

#!/bin/sh
### O2 Homebox 2 (6441) Reconnect/Reboot script ###

ROUTER_HOST="192.168.1.X"
PWD_HASH="PASSWORD_HASH"

#### HOW TO CREATE PASSWORD_HASH ####
# Hash your router password with an MD5 function and the resulting sum with a sha512 function.
# shell command is
#
#
# echo PASSWORD | md5sum | cut -f 1 -d " " | sha512sum | cut -f 1 -d " "
#
#
####


# send login post request
curl -s -d "pws=$PWD_HASH" "$ROUTER_HOST/login.cgi" > /dev/null

# get the token from index page and save as var
ROUTER_TOKEN=$(curl -s "$ROUTER_HOST/" | 	grep -ioP 'data:image/gif;base64,[a-z0-9+/]+///[a-z0-9+/]{31}\K([^"]+)' | base64 --decode)

# send reboot
#curl -d "action=ui_reboot&httoken=$ROUTER_TOKEN" "$ROUTER_HOST/apply_abstract.cgi"

# send disconnect post request
curl -s -d "action=wan_stop&httoken=$ROUTER_TOKEN" "$ROUTER_HOST/apply_abstract.cgi" > /dev/null

# to be sure
sleep 1

# send connect post request
curl -s -d "action=wan_start&httoken=$ROUTER_TOKEN" "$ROUTER_HOST/apply_abstract.cgi" > /dev/null

# wait for connected state
while true
do
    if curl -s "$ROUTER_HOST/cgi/cgi_diagnostic.js?_tn=$ROUTER_TOKEN" | grep -qiP '"WANConnectStatus0",\s?"?\d+"?,\s?"Connected"'; then
		break
    fi
	sleep 3
done

# send logout request
curl -s -d "" "$ROUTER_HOST/logout.cgi" > /dev/null

Es sind von mir bloss ein paar Kommentare eingefügt und der regex für den Connection Status marginal angepasst worden. Geht bestimmt noch besser aber es läuft.

Gruß

Hallo,

danke für euren Einsatz. Bei mir funktioniert das AutoIt-Script leider auch nicht, ich bekomme die Fehlermeldung "Login request failed" bei gesetztem Passwort. Wenn ich mir den Errorwert ausgeben lasse ist es 3 (= "could not receive response").

Ohne Passwort bekomme ich die Fehlermeldung "Token request failed".

Auch wenn ich nWANConnectStatus0 mit WANConnectStatus0 ersetze bekomme ich weiter den Login-Fehler (aber macht ja Sinn da der Reconnect ja ohne Login garnicht aufgerufen wird). Als Firmware wird bei mir übrigens 1.00(AAJG.0)D9b angezeigt.

leider komme ich damit gar nicht klar,
bräuchte ausführlicher Hilfe - danke
Gruß Boerny